388bbc3290
This updates the libraries dependencies for VFX platform 2023, and adds various new libraries. It also enables Python bindings and switches from static to shared for various libraries. The precompiled libraries for all platforms will be updated to these new versions in the coming weeks. New: Fribidi 1.0.12 Harfbuzz 5.1.0 MaterialX 1.38.6 (shared lib with python bindings) Minizipng 3.0.7 Pybind11 2.10.1 Shaderc 2022.3 Vulkan 1.2.198 Updated: Boost 1.8.0 (shared lib) Cython 0.29.30 Numpy 1.23.2 OpenColorIO 2.2.0 (shared lib with python bindings) OpenImageIO 2.4.6.0 (shared lib with python bindings) OpenSubdiv 3.5.0 OpenVDB 10.0.0 (shared lib with python bindings) OSL 1.12.7.1 (enable nvptx backend) TBB (shared lib) USD 22.11 (shared lib with python bindings, enable hydra) yaml-cpp 0.8.0 Includes contributions by Ray Molenkamp, Brecht Van Lommel, Georgiy Markelov and Campbell Barton. Ref T99618
65 lines
1.6 KiB
CMake
65 lines
1.6 KiB
CMake
# SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
if(UNIX)
|
|
if(APPLE)
|
|
set(_libtoolize_name glibtoolize)
|
|
else()
|
|
set(_libtoolize_name libtoolize)
|
|
endif()
|
|
|
|
set(_required_software
|
|
autoconf
|
|
automake
|
|
bison
|
|
${_libtoolize_name}
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
tclsh
|
|
yasm
|
|
)
|
|
|
|
if(APPLE)
|
|
list(APPEND _required_software dos2unix)
|
|
else()
|
|
list(APPEND _required_software patchelf)
|
|
endif()
|
|
|
|
foreach(_software ${_required_software})
|
|
find_program(_software_find NAMES ${_software})
|
|
if(NOT _software_find)
|
|
set(_software_missing "${_software_missing}${_software} ")
|
|
endif()
|
|
unset(_software_find CACHE)
|
|
endforeach()
|
|
|
|
if(APPLE)
|
|
# Homebrew has different default locations for ARM and Intel macOS.
|
|
if("${CMAKE_HOST_SYSTEM_PROCESSOR}" STREQUAL "arm64")
|
|
set(HOMEBREW_LOCATION "/opt/homebrew")
|
|
else()
|
|
set(HOMEBREW_LOCATION "/usr/local")
|
|
endif()
|
|
if(NOT EXISTS "${HOMEBREW_LOCATION}/opt/bison/bin/bison")
|
|
string(APPEND _software_missing " bison")
|
|
endif()
|
|
endif()
|
|
|
|
if(_software_missing)
|
|
message(
|
|
"\n"
|
|
"Missing software for building Blender dependencies:\n"
|
|
" ${_software_missing}\n"
|
|
"\n"
|
|
"On Debian and Ubuntu:\n"
|
|
" apt install autoconf automake bison libtool yasm tcl ninja-build meson python3-mako patchelf\n"
|
|
"\n"
|
|
"On macOS (with homebrew):\n"
|
|
" brew install autoconf automake bison dos2unix flex libtool meson ninja pkg-config yasm\n"
|
|
"\n"
|
|
"Other platforms:\n"
|
|
" Install equivalent packages.\n")
|
|
message(FATAL_ERROR "Install missing software before continuing")
|
|
endif()
|
|
endif()
|