097a13f5be
Commit c8dd33f5a37b6a6db0b6950d24f9a7cff5ceb799 in OSL changed behavior of shader parameters that reference each other and are also overwritten with an instance value. This is causing the "NormalIn" parameter of a few OSL nodes in Cycles to be set to zero somehow, which should instead have received the value from a "node_geometry" node Cycles generates and connects automatically. I am not entirely sure why that is happening, but these parameters are superfluous anyway, since OSL already provides the necessary data in the global variable "N". So this patch simply removes those parameters (which mimics SVM, where these parameters do not exist either), which also fixes the rendering artifacts that occured with recent OSL. Maniphest Tasks: T101222 Differential Revision: https://developer.blender.org/D16470
75 lines
2.2 KiB
Plaintext
75 lines
2.2 KiB
Plaintext
/* SPDX-License-Identifier: Apache-2.0
|
|
* Copyright 2011-2022 Blender Foundation */
|
|
|
|
#include "stdcycles.h"
|
|
|
|
shader node_normal_map(float Strength = 1.0,
|
|
color Color = color(0.5, 0.5, 1.0),
|
|
string space = "tangent",
|
|
string attr_name = "geom:tangent",
|
|
string attr_sign_name = "geom:tangent_sign",
|
|
output normal Normal = N)
|
|
{
|
|
color mcolor = 2.0 * color(Color[0] - 0.5, Color[1] - 0.5, Color[2] - 0.5);
|
|
int is_backfacing = backfacing();
|
|
|
|
if (space == "tangent") {
|
|
vector tangent;
|
|
vector ninterp;
|
|
float tangent_sign;
|
|
float is_smooth = 0.0;
|
|
|
|
getattribute("geom:is_smooth", is_smooth);
|
|
if (!is_smooth) {
|
|
ninterp = normalize(transform("world", "object", Ng));
|
|
|
|
/* the normal is already inverted, which is too soon for the math here */
|
|
if (is_backfacing) {
|
|
ninterp = -ninterp;
|
|
}
|
|
}
|
|
|
|
// get _unnormalized_ interpolated normal and tangent
|
|
if (getattribute(attr_name, tangent) && getattribute(attr_sign_name, tangent_sign) &&
|
|
(!is_smooth || getattribute("geom:normal_map_normal", ninterp))) {
|
|
// apply normal map
|
|
vector B = tangent_sign * cross(ninterp, tangent);
|
|
Normal = normalize(mcolor[0] * tangent + mcolor[1] * B + mcolor[2] * ninterp);
|
|
|
|
// transform to world space
|
|
Normal = normalize(transform("object", "world", Normal));
|
|
}
|
|
else {
|
|
Normal = normal(0, 0, 0);
|
|
}
|
|
}
|
|
else if (space == "object") {
|
|
Normal = normalize(transform("object", "world", vector(mcolor)));
|
|
}
|
|
else if (space == "world") {
|
|
Normal = normalize(vector(mcolor));
|
|
}
|
|
else if (space == "blender_object") {
|
|
/* strange blender convention */
|
|
mcolor[1] = -mcolor[1];
|
|
mcolor[2] = -mcolor[2];
|
|
|
|
Normal = normalize(transform("object", "world", vector(mcolor)));
|
|
}
|
|
else if (space == "blender_world") {
|
|
/* strange blender convention */
|
|
mcolor[1] = -mcolor[1];
|
|
mcolor[2] = -mcolor[2];
|
|
|
|
Normal = normalize(vector(mcolor));
|
|
}
|
|
|
|
/* invert normal for backfacing polygons */
|
|
if (is_backfacing) {
|
|
Normal = -Normal;
|
|
}
|
|
|
|
if (Strength != 1.0)
|
|
Normal = normalize(N + (Normal - N) * max(Strength, 0.0));
|
|
}
|